TypeError: Errors can only be used with revert statements: "revert MyError(args);", or require functions: "require(condition, MyError(args))".
Ai apelat o eroare custom ca pe o funcție (StocInsuficient(5, 2);) fără revert. O eroare custom nu oprește nimic singură: scrie revert StocInsuficient(5, 2); sau, din 0.8.26, require(conditie, StocInsuficient(5, 2)).
Explicat de Tudor Andrei Dumitrescu, Senior Software Developer, fondatorul Academiei ProgramatorilorActualizat la
Ce înseamnă
O eroare custom (error StocInsuficient(uint256 cerut, uint256 disponibil);) descrie motivul unui revert, cu parametri. Ea nu se „aruncă” singură: o folosești cu revert StocInsuficient(cerut, stoc);, care oprește tranzacția și trimite eroarea apelantului. Dacă o scrii ca pe un apel de funcție, fără revert, compilatorul spune Errors can only be used with revert statements: "revert MyError(args);", or require functions: "require(condition, MyError(args))". (MyError din mesaj e doar un exemplu, nu numele erorii tale).
Greșeala apare des la cei obișnuiți cu throw new Eroare() din alte limbaje sau când transformi un require(cond, "mesaj") în eroare custom și uiți cuvântul revert.
Din Solidity 0.8.26 poți folosi erorile custom și direct în require: require(cerut <= stoc, StocInsuficient(cerut, stoc));. În versiunile mai vechi, mesajul se termina după "revert MyError();".
De ce apare: cauzele frecvente
1Eroare apelată fără revert
if (cantitate > stoc) {
StocInsuficient(cantitate, stoc);
}if (cantitate > stoc) {
revert StocInsuficient(cantitate, stoc);
}revert oprește tranzacția și trimite eroarea cu parametrii ei.
2Varianta cu require (0.8.26+)
require(cantitate <= stoc, "Stoc insuficient");require(cantitate <= stoc, StocInsuficient(cantitate, stoc));Același efect, cu o eroare custom în loc de text.
3Eroare folosită ca valoare
error Interzis();
bool ok = Interzis();error Interzis();
if (!autorizat) revert Interzis();O eroare nu are valoare; se folosește doar pentru a opri execuția.
Repară eroarea, direct în pagină
Contractul Depozit are eroarea custom StocInsuficient, dar funcția scoate o folosește fără revert, iar compilarea dă TypeError: Errors can only be used with revert statements. Repară funcția, ca să oprească tranzacția cu această eroare când se cere mai mult decât e în stoc. Scriptul scoate 3 bucăți din 10 și apoi încearcă să scoată 20.
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
contract Depozit {
error StocInsuficient(uint256 cerut, uint256 disponibil);
uint256 public stoc = 10;
function scoate(uint256 cantitate) external {
if (cantitate > stoc) {
StocInsuficient(cantitate, stoc);
}
stoc -= cantitate;
}
}Stoc: 7 Scoate 20: StocInsuficient(20, 7)
Indiciu
O eroare custom se folosește cu revert în față.
Reparația
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
contract Depozit {
error StocInsuficient(uint256 cerut, uint256 disponibil);
uint256 public stoc = 10;
function scoate(uint256 cantitate) external {
if (cantitate > stoc) {
revert StocInsuficient(cantitate, stoc);
}
stoc -= cantitate;
}
}De ce merge
O eroare custom doar descrie motivul; revert e instrucțiunea care oprește tranzacția, anulează modificările și trimite eroarea, cu parametrii ei, apelantului. Prima scoatere lasă 7 bucăți în stoc, iar a doua e respinsă cu StocInsuficient(20, 7). Scriptul primește eroarea cu ambii parametri, ceea ce ajută la depanare.
Alte forme ale mesajului
TypeError: Errors can only be used with revert statements: "revert MyError();".
Cum o eviți pe viitor
- Scrie mereu erorile custom împreună cu
revertsau înrequire(conditie, Eroare(...)). - Pune parametri în erori: cât s-a cerut și cât era disponibil ajută la depanare.
- În teste, verifică eroarea cu
revertedWithCustomError(contract, "StocInsuficient"). - Declară erorile la începutul contractului, ca să fie ușor de găsit.
Întrebări frecvente
De ce să folosesc erori custom în loc de mesaje text?
Sunt mai ieftine (doar un selector de 4 bytes plus parametrii, în loc de tot textul), au parametri și pot fi decodate de ethers din ABI. Mesajele text sunt mai ușor de citit direct în consolă.
Merge require cu eroare custom în versiunea mea?
Din 0.8.26 cu compilatorul IR, iar din 0.8.27 și cu cel obișnuit. În cursul nostru (0.8.30) merge. Pe versiuni mai vechi, folosește if (...) revert Eroare(...);.
Erori înrudite
VM Exception while processing transaction: reverted with custom error 'StocInsuficient(5, 5)' Contractul a oprit tranzacția cu o eroare custom (declarată cu error Nume(...) și aruncată cu revert Nume(...)). Numele îți spune ce regulă a picat, iar valorile dintre paranteze sunt argumentele cu care a fost aruncată. Caută revert-ul în contract și compară condiția cu valorile primite. VM Exception while processing transaction: reverted with reason string 'Plata insuficienta' Un require (sau revert) din contract a oprit tranzacția, iar textul dintre ghilimele este chiar mesajul scris în cod. Caută mesajul în contract, vezi ce condiție verifică și află de ce n-a fost îndeplinită: argumente greșite, alt cont, prea puțin ether sau o condiție scrisă greșit. TypeError: Event invocations have to be prefixed by "emit". Ai apelat un eveniment ca pe o funcție, Intrare(msg.sender), fără cuvântul emit. Din Solidity 0.5 evenimentele se declanșează doar cu emit: emit Intrare(msg.sender); Învață Solidity de la zero, cu exerciții la fiecare lecție
Curs Solidity și Smart Contracts: lecții scurte, fiecare cu un exercițiu verificat automat, direct în browser. Primele 15 lecții sunt gratuite.
