...
Eroare Solidity · Importuri și erorile OpenZeppelin

TypeError: No arguments passed to the base constructor. Specify the arguments or mark "Magazin" as abstract.

Pe scurt

Contractul părinte are un constructor cu parametri (de exemplu Ownable din OpenZeppelin 5 cere proprietarul inițial), iar tu nu i-ai dat argumentele. Adaugă-le în constructorul tău: constructor() Ownable(msg.sender) {}.

Explicat de Tudor Andrei Dumitrescu, Senior Software Developer, fondatorul Academiei ProgramatorilorActualizat la

Ce înseamnă

Când moștenești un contract al cărui constructor are parametri, trebuie să-i dai valorile, altfel părintele nu poate fi inițializat. Mesajul îți spune asta și îți dă două opțiuni: dai argumentele sau marchezi contractul tău abstract (atunci copilul lui va trebui să le dea).

Argumentele se pot da în două locuri:

  • în constructorul tău, ca modifier: constructor() Ownable(msg.sender) ERC20("Leu", "LEU") { };
  • direct în lista de moștenire, dacă sunt constante: contract Token is ERC20("Leu", "LEU").

Eroarea a devenit foarte frecventă odată cu OpenZeppelin 5: în versiunea 4, Ownable avea un constructor fără parametri (proprietar devenea automat msg.sender), iar în versiunea 5 cere explicit initialOwner. Codul din tutorialele vechi, contract X is Ownable { constructor() { } }, nu mai compilează.

De ce apare: cauzele frecvente

1Ownable din OpenZeppelin 5 fără proprietarul inițial

Greșit
SOLIDITY
contract Magazin is Ownable {
    constructor() {}
}
Corect
SOLIDITY
contract Magazin is Ownable {
    constructor() Ownable(msg.sender) {}
}

Ownable(msg.sender) face din cel care publică proprietarul inițial.

2ERC20 fără nume și simbol

Greșit
SOLIDITY
contract Leu is ERC20 {
    constructor() {
        _mint(msg.sender, 1000 ether);
    }
}
Corect
SOLIDITY
contract Leu is ERC20 {
    constructor() ERC20("Leu Digital", "LEU") {
        _mint(msg.sender, 1000 ether);
    }
}

Constructorul lui ERC20 cere numele și simbolul tokenului.

3Contractul tău de bază are constructor cu parametri

Greșit
SOLIDITY
contract Cont { uint256 public limita; constructor(uint256 l) { limita = l; } }
contract ContPremium is Cont {
    constructor() {}
}
Corect
SOLIDITY
contract Cont { uint256 public limita; constructor(uint256 l) { limita = l; } }
contract ContPremium is Cont {
    constructor() Cont(10000) {}
}

Orice părinte cu parametri în constructor trebuie inițializat de copil.

Repară tu

Repară eroarea, direct în pagină

Contractul Magazin nu se compilează și dă TypeError: No arguments passed to the base constructor. El moștenește Ownable (versiunea OpenZeppelin 5 din editor, ./Ownable.sol), al cărui constructor cere proprietarul inițial. Fă-l pe cel care publică proprietarul. Scriptul publică magazinul din contul anei, schimbă prețul, apoi îl pune pe bogdan să încerce același lucru.

Codul care dă eroarea
SOLIDITY
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

contract Magazin is Ownable {
    uint256 public pret = 100;

    constructor() {}

    function seteazaPret(uint256 nou) external onlyOwner {
        pret = nou;
    }
}
După reparație, programul afișează
Proprietar este ana: true
Preț nou: 120
Bogdan: OwnableUnauthorizedAccount
Indiciu

Dă argumentul în constructorul tău: constructor() Ownable(...) {}.

Alte forme ale mesajului

  • TypeError: No arguments passed to the base constructor. Specify the arguments or mark "Token" as abstract.

Cum o eviți pe viitor

  • Când moștenești un contract, uită-te la constructorul lui și dă-i parametrii din prima.
  • Când copiezi cod pentru OpenZeppelin, verifică versiunea: în 5.x, Ownable(initialOwner) e obligatoriu.
  • Pentru flexibilitate, primește proprietarul ca parametru: constructor(address proprietar) Ownable(proprietar) {}, util când un factory publică pentru alții.

Întrebări frecvente

De ce codul din tutorial mergea și la mine nu?

Probabil tutorialul folosea OpenZeppelin 4, unde Ownable nu avea parametri în constructor. În OpenZeppelin 5 proprietarul inițial se dă explicit, ca să nu ajungă din greșeală proprietar un contract factory sau un script de deploy.

În ce ordine rulează constructorii părinților?

În ordinea moștenirii (liniarizarea), de la cel mai de bază la cel mai derivat, indiferent de ordinea în care scrii modifierii în constructorul tău.

Erori înrudite

← Toate erorile Solidity

Tudor Andrei Dumitrescu
Cine a explicat eroarea

Tudor Andrei Dumitrescu

Senior Software Developer · fondatorul Academiei Programatorilor

LinkedIn
  1. 2019 Junior JavaCognizant Softvision
  2. 2021 Mid JavaCognizant Softvision
  3. 2022 Team LeaderEndava
  4. 2023 Senior Software DeveloperUniCredit
  5. Acum Senior Software DeveloperHCLTech
Certificat de absolvire Instructor / Preparator formare, Tudor Andrei Dumitrescu
Certificat de formator autorizatMinisterul Muncii și Ministerul Educației · 2022
Certificat de absolvire Instructor / Preparator formare, Tudor Andrei Dumitrescu

Certificat de formator autorizat · Ministerul Muncii și Ministerul Educației · 2022

Din 2020 construiește Academia Programatorilor, iar din 2026 și JoburiIT.ro. Fiecare eroare de aici a fost reprodusă în editorul nostru: codul greșit chiar dă mesajul din titlu, iar reparația chiar funcționează.

Învață Solidity de la zero, cu exerciții la fiecare lecție

Curs Solidity și Smart Contracts: lecții scurte, fiecare cu un exercițiu verificat automat, direct în browser. Primele 15 lecții sunt gratuite.