TypeError: Struct containing a (nested) mapping cannot be constructed.
Un struct care conține un mapping nu poate fi creat cu Propunere(...) și nu poate exista în memory. Adaugă un element gol direct în storage, cu Propunere storage p = propuneri.push();, apoi setează câmpurile pe rând.
Explicat de Tudor Andrei Dumitrescu, Senior Software Developer, fondatorul Academiei ProgramatorilorActualizat la
Ce înseamnă
Un mapping există doar în storage: nu are lungime, nu poate fi copiat și nu poate fi pus în memory. De aceea, un struct care conține un mapping (de exemplu mapping(address => bool) aVotat) nu poate fi construit ca valoare, cu Propunere(titlu, 0), pentru că expresia ar crea struct-ul în memory și apoi l-ar copia în storage.
Forma corectă creează elementul direct în storage: propuneri.push() fără argumente adaugă un element gol la finalul array-ului și îl întoarce ca referință storage. Apoi setezi câmpurile pe rând. Pentru un mapping de struct-uri, Propunere storage p = propuneri[id]; îți dă direct referința.
Aceeași regulă dă și varianta Type struct ... memory is only valid in storage because it contains a (nested) mapping, când declari o variabilă memory de acest tip.
De ce apare: cauzele frecvente
1push cu un struct construit
propuneri.push(Propunere(titlu, 0));Propunere storage p = propuneri.push();
p.titlu = titlu;push() fără argumente creează elementul direct în storage; câmpurile se setează apoi pe rând.
2Variabilă memory de un tip cu mapping
Propunere memory p = propuneri[id];Propunere storage p = propuneri[id];Struct-ul cu mapping nu poate fi copiat în memory; lucrezi cu o referință storage.
3Struct cu mapping într-un mapping
propuneriDupaId[id] = Propunere(titlu, 0);Propunere storage p = propuneriDupaId[id];
p.titlu = titlu;Elementul unui mapping există deja (gol); îl iei ca referință și îl completezi.
Repară eroarea, direct în pagină
Contractul Sondaj ține propunerile într-un array de struct-uri, iar fiecare propunere are un mapping cu cei care au votat. Compilarea dă TypeError: Struct containing a (nested) mapping cannot be constructed. Repară funcția adauga, ca să creeze propunerea direct în storage. Scriptul adaugă „Pizza”, ana și bogdan votează, apoi ana încearcă să voteze din nou.
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
contract Sondaj {
struct Propunere {
string titlu;
uint256 voturi;
mapping(address => bool) aVotat;
}
Propunere[] public propuneri;
function adauga(string memory titlu) external {
propuneri.push(Propunere(titlu, 0));
}
function voteaza(uint256 id) external {
Propunere storage p = propuneri[id];
require(!p.aVotat[msg.sender], "Ai votat deja");
p.aVotat[msg.sender] = true;
p.voturi += 1;
}
}Pizza are 2 voturi Ana din nou: Ai votat deja
Indiciu
propuneri.push() fără argumente întoarce noul element ca referință storage.
Reparația
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
contract Sondaj {
struct Propunere {
string titlu;
uint256 voturi;
mapping(address => bool) aVotat;
}
Propunere[] public propuneri;
function adauga(string memory titlu) external {
Propunere storage p = propuneri.push();
p.titlu = titlu;
}
function voteaza(uint256 id) external {
Propunere storage p = propuneri[id];
require(!p.aVotat[msg.sender], "Ai votat deja");
p.aVotat[msg.sender] = true;
p.voturi += 1;
}
}De ce merge
Un mapping trăiește doar în storage, așa că un struct care îl conține nu poate fi construit ca valoare și copiat. propuneri.push() fără argumente adaugă un element gol direct în storage și întoarce o referință la el; prin ea setezi titlul, iar voturile și mapping-ul pornesc de la zero. Getter-ul public întoarce doar câmpurile simple, titlul și voturile.
Alte forme ale mesajului
TypeError: Type struct Sondaj.Propunere memory is only valid in storage because it contains a (nested) mapping.
Cum o eviți pe viitor
- Dacă un struct are nevoie de un mapping, creează-l doar cu
push()sau prin referințăstorage. - Alternativ, scoate mapping-ul din struct:
mapping(uint256 => mapping(address => bool)) aVotat;, indexat după id. Struct-ul rămâne simplu și se poate construi și întoarce din funcții. - Nu întoarce struct-uri cu mapping din funcții publice: fă getter-e pentru fiecare câmp.
- Getter-ul automat al unui array public de astfel de struct-uri sare peste mapping.
Întrebări frecvente
Care variantă e mai bună: mapping în struct sau mapping separat?
Mapping-ul separat (aVotat[id][adresa]) e mai flexibil: struct-ul poate fi creat cu Propunere(...), copiat în memory și întors din funcții. Mapping-ul în struct e comod când toate datele unei propuneri trebuie să stea împreună.
Pot șterge un astfel de struct cu delete?
Poți, dar delete nu golește mapping-ul din interior (nu știe ce chei are). Valorile vechi rămân, iar un element nou creat în același loc le-ar vedea.
Erori înrudite
TypeError: Data location must be "storage", "memory" or "calldata" for variable, but none was given. O variabilă locală de tip struct, array sau string trebuie să spună dacă e o referință la datele contractului (storage) sau o copie temporară (memory). Dacă vrei să modifici datele salvate, scrie Produs storage p = produse[id]; dacă doar citești, memory. TypeError: Wrong argument count for function call: 1 arguments given but expected 2. Apelezi o funcție, un eveniment, o eroare custom sau un constructor cu alt număr de argumente decât are în declarație. Compară apelul cu declarația și dă exact câte valori cere, în aceeași ordine. TypeError: Member "push" is not available in uint256[] memory outside of storage. push() și pop() există doar pentru array-urile din storage. Un array memory are lungimea fixă, stabilită la creare cu new uint256[](n). Creează-l cu lungimea potrivită și scrie elementele după index, sau folosește un array de stare. Învață Solidity de la zero, cu exerciții la fiecare lecție
Curs Solidity și Smart Contracts: lecții scurte, fiecare cu un exercițiu verificat automat, direct în browser. Primele 15 lecții sunt gratuite.
