TypeError: Built-in unary operator delete cannot be applied to type mapping(address => bool).
Nu poți șterge un mapping întreg cu delete, pentru că Solidity nu știe ce chei au fost scrise. Șterge cheile una câte una (ține o listă cu ele) sau folosește o rundă: mapping(uint256 => mapping(address => bool)) și treci la runda următoare.
Explicat de Tudor Andrei Dumitrescu, Senior Software Developer, fondatorul Academiei ProgramatorilorActualizat la
Ce înseamnă
Un mapping nu are lungime și nu are o listă de chei: orice cheie posibilă „există” și are valoarea implicită, iar valorile scrise stau în sloturi calculate din hash-ul cheii. De aceea delete votat; nu poate fi implementat: contractul ar trebui să parcurgă un număr infinit de chei. Compilatorul respinge operația cu mesajul de mai sus.
delete votat[ana] funcționează (șterge o singură cheie). La fel, delete pe o structură care conține un mapping șterge celelalte câmpuri, dar lasă mapping-ul neatins.
Variantele uzuale pentru „resetare”:
- păstrezi un array cu cheile scrise și le ștergi într-o buclă (merge pentru liste mici);
- folosești un contor de rundă:
mapping(uint256 => mapping(address => bool)) votat;șirunda++la resetare. Datele vechi rămân, dar nu mai sunt citite; costul resetării e constant.
De ce apare: cauzele frecvente
1Resetarea unui vot
function reseteaza() external {
delete aVotat;
delete votanti;
}function reseteaza() external {
for (uint256 i = 0; i < votanti.length; i++) {
delete aVotat[votanti[i]];
}
delete votanti;
}Lista votanti spune ce chei au fost scrise, deci pot fi șterse una câte una.
2Resetare cu runde, fără buclă
mapping(address => bool) public aVotat;
function reseteaza() external { delete aVotat; }uint256 public runda;
mapping(uint256 => mapping(address => bool)) public aVotat;
function reseteaza() external { runda++; }Verificările folosesc aVotat[runda][msg.sender]; o rundă nouă pornește goală.
Repară eroarea, direct în pagină
Contractul Vot ține minte cine a votat într-un mapping și resetează votul, dar compilarea dă TypeError: Built-in unary operator delete cannot be applied to type mapping(address => bool). În reseteaza, șterge cheile una câte una, parcurgând lista votanti, apoi golește lista. Scriptul: ana și bogdan votează, votul se resetează, iar ana votează din nou.
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
contract Vot {
mapping(address => bool) public aVotat;
address[] public votanti;
uint256 public voturi;
function voteaza() external {
require(!aVotat[msg.sender], "Ai votat deja");
aVotat[msg.sender] = true;
votanti.push(msg.sender);
voturi++;
}
function reseteaza() external {
delete aVotat;
delete votanti;
voturi = 0;
}
}Voturi: 1 Bogdan a votat: false
Indiciu
delete aVotat[adresa] merge pentru o singură cheie.
Reparația
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
contract Vot {
mapping(address => bool) public aVotat;
address[] public votanti;
uint256 public voturi;
function voteaza() external {
require(!aVotat[msg.sender], "Ai votat deja");
aVotat[msg.sender] = true;
votanti.push(msg.sender);
voturi++;
}
function reseteaza() external {
for (uint256 i = 0; i < votanti.length; i++) {
delete aVotat[votanti[i]];
}
delete votanti;
voturi = 0;
}
}De ce merge
Un mapping nu are o listă de chei, deci delete aVotat nu poate ști ce să șteargă, iar compilatorul îl respinge. Lista votanti rezolvă problema: bucla șterge fiecare cheie scrisă, apoi delete votanti golește array-ul. După resetare, ana poate vota din nou (1 vot), iar bogdan apare ca nevotat.
Alte forme ale mesajului
TypeError: Built-in unary operator delete cannot be applied to type mapping(address => uint256).
Cum o eviți pe viitor
- Când știi că vei avea nevoie de resetare, proiectează de la început cu runde sau cu o listă de chei.
- Bucla peste chei e sigură doar pentru liste mici: la sute de elemente poți depăși limita de gas.
deletepe o cheie (delete m[k]) e în regulă și îți dă înapoi o parte din gas.
Întrebări frecvente
Pot afla câte chei are un mapping?
Nu. Dacă îți trebuie numărul sau lista, ține-le separat: un contor sau un array, actualizate la fiecare scriere.
Ce se întâmplă cu un mapping dintr-o structură ștearsă cu delete?
Rămâne neatins. Celelalte câmpuri devin 0, dar valorile din mapping se pot citi în continuare, ceea ce poate surprinde: e o sursă cunoscută de bug-uri.
Erori înrudite
TypeError: Types in storage containing (nested) mappings cannot be assigned to. Ai încercat să copiezi dintr-o variabilă de stare în alta o structură (sau un mapping) care conține un mapping. Mapping-urile nu se pot copia, pentru că nu au o listă de chei. Copiază câmpurile simple unul câte unul și lasă mapping-ul deoparte. TypeError: Member "length" is read-only and cannot be used to resize arrays. Din Solidity 0.6, lungimea unui array nu se mai poate seta (lista.length = 0 sau lista.length--). Ca să golești array-ul folosește delete lista, ca să scoți ultimul element folosește lista.pop(), iar ca să adaugi, lista.push(x). Transaction ran out of gas Tranzacția a consumat tot gas-ul pe care l-a primit (gasLimit) înainte să se termine, de obicei din cauza unei bucle care scrie de multe ori în storage sau a unei limite de gas setate prea mic. Fă funcția să lucreze în pași constanți (fără bucle care cresc cu datele) sau mărește gasLimit-ul. Învață Solidity de la zero, cu exerciții la fiecare lecție
Curs Solidity și Smart Contracts: lecții scurte, fiecare cu un exercițiu verificat automat, direct în browser. Primele 15 lecții sunt gratuite.
